Graphe Héloïse

Contenu du graphe

Ce graphe expérimental contient les données fournies par trois différents projets participants au Réseau européen sur les bases de données historiques sur les universités Héloïse :

  • Irish in Europe Project (National University of Ireland, Maynooth)
  • Onomasticon (Prosopografia dell'Università degli Studi di Perugia)
  • Projet ASFE (Università di Bologna)
  • Studium Parisiense (LAMOP, Université de Paris 1)

Les données sont structurées avec l'ontologie symogih.org.
Attention, ne cliquez pas sur les URI, celles-ci ne sont pas encore déréférencés.


Quelques requêtes SPARQL

Ces requêtes sont à saisir dans le champ "Query text" de l'éditeur de requêtes SPARQL Virtuoso, à la place de l'exemple.

La liste des préfixes doit être insérée en haut de chaque requête :

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX viaf: <http://viaf.org/viaf/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX sym: <http://symogih.org/ontology/>
PREFIX syr: <http://symogih.org/resource/>


Liste des individus


SELECT *
WHERE
{ GRAPH <http://symogih.org/graph/heloise>
{ ?s sym:hasObjectType syr:Actor .
?s sym:standardActorName ?name
}
}


List des individus avec leurs date et lieu de naissance

Les données sont structurées en utilisant le type d'unité de connaissance de symogih.org Naissance – TyIn14.
Les lieux d'origines sont intentionnellement "forcés" comme étant des lieux de naissance pour souligner le besoin de réflexion sur l'alignement du modèle de données.

SELECT ?o ?name ?s ?birthDate ?dateCertainty ?placeOfBirth ?placeOfOrigin
WHERE
{ GRAPH <http://symogih.org/graph/heloise>
{ ?s sym:hasKnowledgeUnitType syr:TyIn14 .
?r sym:isComponentOf ?s .
?r sym:associatesObject ?o .
?o sym:standardActorName ?name
OPTIONAL
{ ?d sym:dates ?s .
?d sym:dateTime ?birthDate .
?d sym:datingCertainty ?dateCertainty
}
OPTIONAL
{ ?r1 sym:isComponentOf ?s .
?r1 sym:hasRoleType syr:TyRo16 .
?r1 sym:roleObjectLabelAccordingToSource ?placeOfOrigin
}
OPTIONAL
{ ?r2 sym:isComponentOf ?s .
?r2 sym:hasRoleType syr:TyRo8 .
?r2 sym:roleObjectLabelAccordingToSource ?placeOfBirth
}
}
}
ORDER BY ?name

Visualiser cette requête comme une table