Projet SIPROJURIS – données publiées au format RDF en utilisant l'ontologie du projet symogih.org

Contenu du graphe Siprojuris

Ce graphe contient les données publiées sur le site web du projet SIPROJURIS.

Les données sont publiées au format RDF et structurées en utilisant l'ontologie du projet symogih.org.

Le schéma de l'ontologie générique, à la fois aux formats RDF et PDF, peut être téléchargée depuis ce lien.
Pour visualiser cette ontologie, vous pouvez utiliser le site Webvowl : en cliquant sur le menu "Ontology" en bas de la page, vous pourrez télécharger ("upload") le fichier RDF contenu dans l'archive ZIP.

Les instances (ou sous-classes) de l'ontologie sont documentées sur ce site même.

Pour une présentation succincte, en anglais, de l'ontologie du projet symogih.org, voir Francesco Beretta / Thomas Riechert, Collaborative Research on Academic History using Linked Open Data: A Proposal for the Heloise Common Research Model, CIAN - Revista de Historia de las Universidades, 2016, 19 (1), pp.133-151:141-145. Pour une présentation détaillée, en français, voir Francesco Beretta, L'interopérabilité des données historiques et la question du modèle : l'ontologie du projet SyMoGIH, dans : Brigitte Juanals et Jean-Luc Minel. Enjeux numériques pour les médiations scientifiques et culturelles du passé , Presses universitaires de Paris Nanterre, 2017, p.87-127.

Défi données MaDICS-ADOC 2018

Voici les pages dédiées au défi présenté lors de la conférence INFORSID 2018.

Analyse de la structure des données

Les requêtes SPARQL ci-dessous sont à saisir dans le champ "Query text" de l'éditeur de requêtes SPARQL, en remplaçant l'exemple.

Pour liste des préfixes voir cette page. Ces préfixes peuvent être utilisés sans les déclarer explicitement dans la requête.

ATTENTION: afin de voir uniquement les données du projet Siprojuris, déclarer le graphe
https://dataforhumanities.org/sparql-endpoint/siprojuris-sym
comme 'default graph' (coller l'URI dans le champs 'Default Data Set Name (Graph IRI)')
Remarque: les URI ne sont pas toutes déréférencées, par conséquent dans l'affichage HTML de la réponse certains liens conduisent vers des pages non-existantes.

Structure de la partie abstraite de l'ontologie


SELECT ?cl ?p ?cl1 (COUNT(*) as ?effectif)
WHERE {
{?s a ?cl.
?s ?p ?o1.
OPTIONAL {?o1 a ?cl1}}
}
GROUP BY ?cl ?p ?cl1
ORDER BY ?cl ?p ?effectif


Structure de la partie instanciée de l'ontologie

Types d'informations et types de rôles, avec effectifs

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX viaf: <http://viaf.org/viaf/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX sym: <http://symogih.org/ontology/>
PREFIX syr: <http://symogih.org/resource/>

SELECT ?tyin ?tyro (COUNT(*) as ?effectif)
WHERE {GRAPH <https://dataforhumanities.org/sparql-endpoint/siprojuris-sym>
{?s sym:hasKnowledgeUnitType ?tyin.
?r sym:isComponentOf ?s.
?r sym:hasRoleType ?tyro}
}
GROUP BY ?tyin ?tyro
ORDER BY ?tyin ?tyro ?effectif

Le parcours biographique de Gaston,Louis, Henry May (1849 - 1940)


SELECT ?TyRoLabel ?infoStandardDate ?infoStandardLabel ?TyInLabel
WHERE
{GRAPH <https://dataforhumanities.org/sparql-endpoint/symogih-kute>
{
?tyro rdfs:label ?TyRoLabel.
?tyin rdfs:label ?TyInLabel.

{GRAPH <https://dataforhumanities.org/sparql-endpoint/siprojuris-sym>
{?s ?p syr:Actr56241;
sym:isComponentOf ?info;
sym:hasRoleType ?tyro.
?info sym:knowledgeUnitStandardLabel ?infoStandardLabel;
sym:knowledgeUnitStandardDate ?infoStandardDate;
sym:hasKnowledgeUnitType ?tyin.
}
}
}
}
ORDER BY ?infoStandardDate